Cubic splines

5.3. Cubic splines#

A piecewise linear interpolant is continuous but has discontinuities in its derivative. We often desire a smoother interpolant, i.e., one that has some continuous derivatives. By far the most popular choice is piecewise cubic.

Definition 5.3.1 : Cubic spline

A cubic spline is a piecewise cubic function that has two continuous derivatives everywhere.

We use $S (x)$ to denote the cubic spline interpolant. As before, suppose that distinct nodes $t_{0} < t_{1} < \dots < t_{n}$ (not necessarily equally spaced) and data $y_{0}, \dots, y_{n}$ are given. For any $k = 1, \dots, n$ , the spline $S (x)$ on the interval $[t_{k - 1}, t_{k}]$ is by definition a cubic polynomial $S_{k} (x)$ , which we express as

(5.3.1)#

S_{k} (x) = a_{k} + b_{k} (x - t_{k - 1}) + c_{k} (x - t_{k - 1})^{2} + d_{k} (x - t_{k - 1})^{3}, k = 1, \dots, n,

where $a_{k}, b_{k}, c_{k}, d_{k}$ are values to be determined. Overall there are $4 n$ such undetermined coefficients.

Smoothness conditions#

We are able to ensure that $S$ has at least two continuous derivatives everywhere by means of the following constraints.

1. Interpolation by $S_{k}$ at both of its endpoints.

Algebraically we require $S_{k} (t_{k - 1}) = y_{k - 1}$ and $S_{k} (t_{k}) = y_{k}$ for every $k = 1, \dots, n$ . In terms of (5.3.1), these conditions are

(5.3.2)#

a_{k} = y_{k - 1},

(5.3.3)#

a_{k} + b_{k} h_{k} + c_{k} h_{k}^{2} + d_{k} h_{k}^{3} = y_{k}, k = 1, \dots, n,

where we have used the definition

(5.3.4)#

h_{k} = t_{k} - t_{k - 1}, k = 1, \dots, n .

The values of $h_{k}$ are derived from the nodes. Crucially, the unknown coefficients appear only linearly in the constraint equations. So we will express the constraints using linear algebra. The left endpoint interpolation constraints (5.3.2) are, in matrix form,

(5.3.5)#

\begin{array}{r} [\begin{array}{c} I & 0 & 0 & 0 \end{array}] [\begin{array}{c} a \\ b \\ c \\ d \end{array}] = [\begin{array}{c} y_{0} \\ ⋮ \\ y_{n - 1} \end{array}], \end{array}

with $I$ being an $n \times n$ identity. The right endpoint interpolation constraints, given by (5.3.3), become

(5.3.6)#

\begin{array}{r} [\begin{array}{c} I & H & H^{2} & H^{3} \end{array}] [\begin{array}{c} a \\ b \\ c \\ d \end{array}] = [\begin{array}{c} y_{1} \\ ⋮ \\ y_{n} \end{array}], \end{array}

where we have defined the diagonal matrix

(5.3.7)#

\begin{array}{r} H = [\begin{array}{c} h_{1} \\ h_{2} \\ ⋱ \\ h_{n} \end{array}] . \end{array}

Collectively, (5.3.5) and (5.3.6) express $2 n$ scalar constraints on the unknowns.

2. Continuity of $S^{'} (x)$ at interior nodes.

We do not know what the slope of the interpolant should be at the nodes, but we do want the same slope whether a node is approached from the left or the right. Thus we obtain constraints at the nodes that sit between two neighboring piecewise definitions, so that $S_{1}^{'} (t_{1}) = S_{2}^{'} (t_{1})$ , and so on. Altogether these are

(5.3.8)#

b_{k} + 2 c_{k} h_{k} + 3 d_{k} h_{k}^{2} = b_{k + 1}, k = 1, \dots, n - 1.

Moving the unknowns to the left side, as a system these become

(5.3.9)#

\begin{array}{r} E [\begin{array}{c} 0 & J & 2 H & 3 H^{2} \end{array}] [\begin{array}{c} a \\ b \\ c \\ d \end{array}] = 0, \end{array}

where now we have defined

(5.3.10)#

\begin{array}{r} J = [\begin{array}{c} 1 & - 1 \\ 1 & - 1 \\ ⋱ & ⋱ \\ 1 & - 1 \\ 1 \end{array}], \end{array}

and $E$ is the $(n - 1) \times n$ matrix resulting from deleting the last row of the identity:

(5.3.11)#

\begin{array}{r} E = [\begin{array}{c} 1 & 0 \\ 1 & 0 \\ ⋱ & ⋱ \\ 1 & 0 \end{array}] . \end{array}

Left-multiplying by $E$ deletes the last row of any matrix or vector. Hence (5.3.9) represents $n - 1$ constraints on the unknowns. (Remember, there are only $n - 1$ interior nodes.)

3. Continuity of $S^{″} (x)$ at interior nodes.

These again apply only at the interior nodes $t_{1}, \dots, t_{n - 1}$ , in the form $S_{1}^{″} (t_{1}) = S_{2}^{″} (t_{1})$ and so on. Using (5.3.1) once more, we obtain

(5.3.12)#

2 c_{k} + 6 d_{k} h_{k} = 2 c_{k + 1}, k = 1, \dots, n - 1.

In system form (after canceling a factor of 2 from each side) we get

(5.3.13)#

\begin{array}{r} E [\begin{array}{c} 0 & 0 & J & 3 H \end{array}] [\begin{array}{c} a \\ b \\ c \\ d \end{array}] = 0 . \end{array}

End conditions#

So far the equations (5.3.5), (5.3.6), (5.3.9), and (5.3.13) form $2 n + (n - 1) + (n - 1) = 4 n - 2$ linear conditions on the $4 n$ unknowns in the piecewise definition (5.3.1). In order to obtain a square system, we must add two more constraints. If the application prescribes values for $S^{'}$ or $S^{″}$ at the endpoints, those may be applied. Otherwise there are two major alternatives:

Natural spline: $S_{1}^{″} (t_{0}) = S_{n}^{″} (t_{n}) = 0$
Not-a-knot spline: $S_{1}^{‴} (t_{1}) = S_{2}^{‴} (t_{1}), S_{n - 1}^{‴} (t_{n - 1}) = S_{n}^{‴} (t_{n - 1})$

While natural splines have important theoretical properties, not-a-knot splines give better pointwise accuracy, and they are the only type we consider further.

In the not-a-knot spline, the values and first three derivatives of the cubic polynomials $S_{1}$ and $S_{2}$ agree at the node $t_{1}$ . Hence they must be the same cubic polynomial! The same is true of $S_{n - 1}$ and $S_{n}$ .1 We could use these facts to eliminate some of the undetermined coefficients from our linear system of constraints. However, rather than rework the algebra we just append two more rows to the system, expressing the conditions

(5.3.14)#

d_{1} = d_{2}, d_{n - 1} = d_{n} .

Collectively, (5.3.5), (5.3.6), (5.3.9), (5.3.13), and (5.3.14) comprise a square linear system of size $4 n$ which can be solved for the coefficients defining the piecewise cubics in (5.3.1). This is a major difference from the piecewise linear interpolant, for which there is no linear system to solve. Indeed, while it is possible to find a basis for the cubic spline interpolant analogous to the hat functions, it is not possible in closed form to construct a cardinal basis, so the solution of a linear system cannot be avoided.

Implementation#

Function 5.3.2 : spinterp

Cubic not-a-knot spline interpolation

"""
    spinterp(t,y)

Construct a cubic not-a-knot spline interpolating function for data
values in `y` given at nodes in `t`.
"""
function spinterp(t,y)
    n = length(t)-1
    h = [ t[k+1]-t[k] for k in 1:n ]

    # Preliminary definitions.
    Z = zeros(n,n);
    In = I(n);  E = In[1:n-1,:];
    J = diagm(0=>ones(n),1=>-ones(n-1))
    H = diagm(0=>h)

    # Left endpoint interpolation:
    AL = [ In Z Z Z ]
    vL = y[1:n]

    # Right endpoint interpolation:
    AR = [ In H H^2 H^3 ];
    vR = y[2:n+1]

    # Continuity of first derivative:
    A1 = E*[ Z J 2*H 3*H^2 ]
    v1 = zeros(n-1)

    # Continuity of second derivative:
    A2 = E*[ Z Z J 3*H ]
    v2 = zeros(n-1)

    # Not-a-knot conditions:
    nakL = [ zeros(1,3*n) [1 -1 zeros(1,n-2)] ]
    nakR = [ zeros(1,3*n) [zeros(1,n-2) 1 -1] ]

    # Assemble and solve the full system.
    A = [ AL; AR; A1; A2; nakL; nakR ]
    v = [ vL; vR; v1; v2; 0; 0 ]
    z = A\v

    # Break the coefficients into separate vectors.
    rows = 1:n
    a = z[rows]
    b = z[n.+rows];  c = z[2*n.+rows];  d = z[3*n.+rows]
    S = [ Polynomial([a[k],b[k],c[k],d[k]]) for k in 1:n ]

    # This function evaluates the spline when called with a value
    # for x.
    return function (x)
        if x < t[1] || x > t[n+1]    # outside the interval
            return NaN
        elseif x==t[1]
            return y[1]
        else
            k = findlast(x .> t)    # last node to the left of x
            return S[k](x-t[k])
        end
    end
end

Function 5.3.2 gives an implementation of cubic not-a-knot spline interpolation. For clarity it stays very close to the description given above. There are some possible shortcuts—for example, one could avoid using $E$ and instead directly delete the last row of any matrix it left-multiplies. Observe that the linear system is assembled and solved just once, and the returned evaluation function simply uses the resulting coefficients. This allows us to make multiple calls to evaluate $S$ without unnecessarily repeating the linear algebra.

Conditioning and convergence#

Demo 5.3.3

For illustration, here is a spline interpolant using just a few nodes.

f = x -> exp(sin(7*x))

plot(f,0,1,label="function",xlabel=L"x",ylabel=L"y")

t = [0, 0.075, 0.25, 0.55, 0.7, 1]  # nodes
y = f.(t)                           # values at nodes

scatter!(t,y,label="values at nodes")

S = FNC.spinterp(t,y)

plot!(S,0,1,label="spline")

Now we look at the convergence rate as the number of nodes increases.

x = (0:10000)/1e4              # sample the difference at many points
n = @. round(Int,2^(3:0.5:7))  # numbers of nodes
err = zeros(0)
for n in n
    t = (0:n)/n 
    S = FNC.spinterp(t,f.(t))
    dif = @. f(x)-S(x)
    push!(err,norm(dif,Inf))
end

pretty_table((;n, err), header=["n","error"])

┌─────┬─────────────┐
│   n │       error │
├─────┼─────────────┤
│   8 │   0.0305634 │
│  11 │   0.0207562 │
│  16 │  0.00590761 │
│  23 │  0.00134587 │
│  32 │ 0.000367049 │
│  45 │  9.17785e-5 │
│  64 │  2.15306e-5 │
│  91 │  5.04292e-6 │
│ 128 │  1.24012e-6 │
└─────┴─────────────┘

Since we expect convergence that is $O (h^{4}) = O (n^{- 4})$ , we use a log-log graph of error and expect a straight line of slope $- 4$ .

order4 = @. (n/n[1])^(-4)

plot(n,[err order4],m=[:o :none],l=[:solid :dash],
    label=["error" "4th order"],
    xaxis=(:log10,"n"), yaxis=(:log10,L"|| f-S\,||_\infty"),
    title="Convergence of spline interpolation")

Besides having more smoothness than a piecewise linear interpolant, the not-a-knot cubic spline improves the order of accuracy to 4.

Theorem 5.3.4

Suppose that $f (x)$ has four continuous derivatives in $[a, b]$ (i.e., $f \in C^{4} [a, b]$ ). Let $S_{n} (x)$ be the not-a-knot cubic spline interpolant of $(t_{i}, f (t_{i}))$ for $i = 0, \dots, n$ , where $t_{i} = a + i h$ and $h = (b - a) / n$ . Then for all sufficiently small $h$ , there is a constant $C > 0$ such that

(5.3.15)#

‖ f - S_{n} ‖_{\infty} \leq C h^{4} .

The conditioning of spline interpolation is much more complicated than for the piecewise linear case. First, the fact that the coefficients of all the cubics must be solved for simultaneously implies that each data value in $y$ has an influence on $S$ over the entire interval. Second, $S$ can take on values larger in magnitude than all of the values in $y$ (see Exercise 5). The details may be found in more advanced texts.

Exercises#

✍ In each case, write out the entries of the matrix and right-hand side of the linear system that determines the coefficients for the cubic not-a-knot spline interpolant of the given function and node vector.

(a) $\cos (π^{2} x^{2}), t = [- 1, 1, 4]$

(b) $\cos (π^{2} x^{2}), t = [0, \frac{1}{2}, \frac{3}{4}, 1]$

(c) $\ln (x), t = [1, 2, 3]$

(d) $\sin (x^{2}), t = [- 1, 0, 1]$
⌨ (continuation) For each case in the preceding problem, use Julia to solve the linear system you wrote down. Then plot the resulting cubic spline over the interval between the second and third nodes.
⌨ For each given function, interval, and value of $n$ , define $n + 1$ evenly spaced nodes. Then use Function 5.3.2 to plot the cubic spline interpolant using those nodes, together with the original function over the given interval.

(a) $\cos (π x^{2})$ on $[0, 4]$ , $n = 18$

(b) $\ln (x)$ on $[1, 20]$ , $n = 4$

(c) $\sin (\frac{1}{x})$ on $[\frac{1}{2}, 7]$ , $n = 9$
⌨ For each given function and interval, perform piecewise linear interpolation using Function 5.3.2 for $n + 1$ equispaced nodes with $n = 10, 20, 40, 80, 160, 320$ . For each $n$ , estimate the error

$E (n) = ‖ f - p ‖_{\infty} = max_{x} | f (x) - p (x) |$

by evaluating the function and interpolant at 1600 points in the interval. Make a log-log plot of $E$ as a function of $n$ and add the line $E = C n^{- 4}$ for a constant $C$ of your choosing.

(a) $\cos (π x^{2})$ on $[0, 4]$

(b) $\ln (x)$ on $[1, 20]$

(c) $\sin (\frac{1}{x})$ on $[\frac{1}{2}, 7]$
⌨ Although the cardinal cubic splines are intractable in closed form, they can be found numerically. Each cardinal spline interpolates the data from one column of an identity matrix. Define the nodes $t = [0, 0.075, 0.25, 0.55, 1]$ . Plot over $[0, 1]$ the five cardinal functions for this node set over the interval $[0, 1]$ .
✍ Suppose you were to define a piecewise quadratic spline that interpolates $n + 1$ given values and has a continuous first derivative. Follow the derivation of this section to express all of the interpolation and continuity conditions. How many additional conditions are required to make a square system for the coefficients?
(a) ✍ If $y_{0} = y_{n}$ , another possibility for cubic spline end conditions is to make $S (x)$ a periodic function. This implies that $S^{'}$ and $S^{″}$ are also periodic. Write out the two new algebraic equations for these constraints in terms of the piecewise coefficients.

(b) ⌨ Modify Function 5.3.2 to compute a periodic spline interpolant. Test by making a plot of the interpolant for $f (x) = \exp (\sin (3 x))$ over the interval $[0, 2 π / 3]$ with equally spaced nodes and $n = 8$ .

1: This explains the name of the not-a-knot spline—for splines, “knots” are the points at which different piecewise definitions meet.